Cómo unificar una estructura de URLs con Excel

Gran parte del trabajo de un SEO consiste en organizar información. Ya sea que se trate de un grupo de keywords o un listado de URLs, siempre conviene tener todo armado de manera más prolija posible para que Google pueda entender sin problemas nuestro contenido. Cuando se habla de estructuras de URLs, la idea es la misma; se debe aplicar, como dijo una vez Francis Petty, la regla de Highlander: «there can be only one».

Si tenemos varias versiones de nuestras URLs tienden a empezar a aparecer problemas. Si existen URLs en tu sitio con ‘http’ y otras con ‘https’, páginas con ‘www’ y otras sin, trailing slashes que aparecen de tanto en tanto, etc. es posible que ciertas partes de tu sitio no se estén indexando como te gustaría (o se estén indexando más de una vez).

Lo que se recomienda es establecer una estructura de URL que sea la canónica con un tag canonical, un sitemap con las URLs canonicalizadas y luego crear las reglas de redirect para que Google encuentre todo y no se pierda nada. Para ayudar un poco con la estructuración vamos a recurrir a Google Sheets o, en su defecto, el Excel.

Para establecer una base, vamos a hacer que todas nuestras URLs tengan los siguientes elementos: protocolo correcto, subdominio visible y un trailing slash al final.

Hay que tener en cuenta que si tu dominio tiene un protocolo normal (aunque te convendría tener un protocolo seguro) entonces se debe escribir ‘http’ y no ‘https’. A continuación te dejamos algunas fórmulas que te puede ahorrar algo de tiempo y trabajo.

Fórmula de Excel para pasar todos los protocolos de una URL a HTTPS:

http://www.sitio.com.ar -> https://www.sitio.com.ar

=SI(IZQUIERDA(A1,7)="http://","https://"&DERECHA(A1,LARGO(A1)-7),A1)

(si los primeros 7 caracteres de la URL son 'http://',
entonces escribí 'https://' y luego
el resto de la URL sin los primeros 7 caracteres)

Fórmula de Excel para agregar ‘www.’ a una URL:

https://sitio.com.ar -> https://www.sitio.com.ar

=SI(ESNUMERO(ENCONTRAR("://www.",A1)),A1,IZQUIERDA(A1,ENCONTRAR("://",A1)+2)&"www."&DERECHA(A1,LARGO(A1)-(ENCONTRAR("://",A1)+2)))

(si está escrito el 'www.' entonces no cambies nada,
sino tomá todo lo que está a la izquierda del '://'
[porque no sabemos si el protocolo es 'http' o 'https'],
agregale el 'www.' y después metele todo
lo que está a la derecha del '://')

 

Fórmula de Excel para agregar un trailing slash a URL que no lo tenga:

https://www.sitio.com.ar -> https://www.sitio.com.ar/

=SI(DERECHA(A1,1)="/",A1,A1&"/")

(si el último caracter de la URL [lit. el primero contando desde la derecha]
es un trailing slash, entonces no hagas nada; sino agregale un trailing slash)

Fórmula de Excel para escribir una estructura de URL optimizada para SEO:

="https://"&SI(ESNUMERO(ENCONTRAR("://www.",A2)),EXTRAE(A2,ENCONTRAR("://",A2)+3,LARGO(A2)),"www."&EXTRAE(A2,ENCONTRAR("://",A2)+3,LARGO(A2)))&SI(DERECHA(A2,1)="/","","/")

(acá se complica el asunto... escribir el protocolo 'https://' y
si ya tiene el subdominio 'www.' entonces no cambies nada y agregá
el resto de la URL, sino agregalo y agregá el resto de la URL.
Si termina en trailing slash no hagas nada, sino agregalo.)

Hay que tener en cuenta que si tenés subdominios en tu listado de URLs se va a romper la regla del subdominio. Te quedaría algo así como www.blog.sitio.com.ar. Se podría agregar una salvedad explicando en una celda cuál es el nombre del dominio (o que lo levante sólo pero se complicaría más todavía el asunto) y hacer que si el caractér anterior a él es un ‘.’ pero no está precedido por un ‘www’… en fin; ya me mareé.

Espero que estas fórmulas de Excel para unificar la estructura de URLs de tu sitio para que sean amigables para SEO les hayan servido. Si conocen de alguna otra forma de lograr esto no duden en dejarnos un comentario. Google Sheet de ejemplo acá.